Another Classic Ported to TRS-80 MC-10

Games for Spectrum, C64, Amstrad, Amiga, Apple ][ and the rest of the 8-bit and 16-bit platforms. Pleas for help, puzzles, bug reports etc.

Moderator: Alastair

Message
Author
User avatar
jgerrie
Posts: 280
Joined: Sat Aug 17, 2013 1:25 pm
Location: Nova Scotia
Contact:

Re: Another Classic Ported to TRS-80 MC-10

#31 Post by jgerrie » Thu Mar 17, 2016 5:29 am

I've ported Williamsburg Adventure by Microdeal to the TRS-80 MC-10.
willburg.png
willburg.png (2.84 KiB) Viewed 3266 times

Colin Appleby
Posts: 93
Joined: Wed Mar 16, 2016 10:05 pm

The Orient Express, 1923 Another Classic Ported to TRS-80 MC

#32 Post by Colin Appleby » Fri Mar 18, 2016 11:19 am

I am interested in "The Orient Express, 1923" listing for TRS-80 MC-10 to convert to NewBrain Basic. Can you advise where I can find the listing. Thanks.

Alastair
Posts: 1046
Joined: Fri Nov 11, 2005 12:21 am

Re: Another Classic Ported to TRS-80 MC-10

#33 Post by Alastair » Sat Mar 19, 2016 12:44 am

There's a complete listing of The Orient Express, 1923, written in Microsoft BASIC (aka BASICA or GW BASIC), towards the end of this page at AtariArchives.org.

User avatar
jgerrie
Posts: 280
Joined: Sat Aug 17, 2013 1:25 pm
Location: Nova Scotia
Contact:

Re: The Orient Express, 1923 Another Classic Ported to TRS-8

#34 Post by jgerrie » Wed Mar 23, 2016 6:26 pm

Colin,

You can find my code on Github for the Micro Color BASIC conversion I made for the MC-10:
https://github.com/jggames/trs80mc10/bl ... RIENT4.TXT

If I recall, the original Microsoft Basic version had some very special tricks meant to hide the solution from code peekers (strange results from special function calls, etc. that relied on features unique to the PC version of that language). I believe I took these out in my version, so it might be a simpler basis for a conversion to the Newbrain. At the very least I would be able to go back and refamiliarize myself with how I got around those features and you help out.
Colin Appleby wrote:I am interested in "The Orient Express, 1923" listing for TRS-80 MC-10 to convert to NewBrain Basic. Can you advise where I can find the listing. Thanks.

Colin Appleby
Posts: 93
Joined: Wed Mar 16, 2016 10:05 pm

Orient Express adventure for the NewBrain

#35 Post by Colin Appleby » Thu Mar 24, 2016 1:06 pm

Have just completed the conversion of "Orient Express" by David H. Ahl in 1986 which is now running on the NewBrain computer.
The Orient Express is standing majestically on Track 14 with Bandits and Snow ahead, on the journey from London to Constantinople.

User avatar
jgerrie
Posts: 280
Joined: Sat Aug 17, 2013 1:25 pm
Location: Nova Scotia
Contact:

Re: Orient Express adventure for the NewBrain

#36 Post by jgerrie » Sat Mar 26, 2016 2:48 am

Way to go:)
Colin Appleby wrote:Have just completed the conversion of "Orient Express" by David H. Ahl in 1986 which is now running on the NewBrain computer.
The Orient Express is standing majestically on Track 14 with Bandits and Snow ahead, on the journey from London to Constantinople.

Colin Appleby
Posts: 93
Joined: Wed Mar 16, 2016 10:05 pm

Listing for Orient Express adventure on the NewBrain

#37 Post by Colin Appleby » Mon Mar 28, 2016 1:28 pm

Program Listing for NewBrain Computer:
1 OPEN#0,0,"L"
5 REM DIGITIZED BY COLIN APPLEBY
6 REM DEBUGGED BY CHRIS DESPINIDIS
7 REM CONVERTED FROM ORGINAL LISTING TO NEWBRAIN BASIC
8 REM DATED 20 MARCH 2016
20 REM SUBROUTINE TO DEAL WITH MISCELLANEOUS HAZARDS
50 OPEN#0,0,"l40": REM 80 CHR SCREEN
60 PRINT "PRESS ANY KEY TO CALL A TAXI"
70 REM SUBROUTINE FOR SNOW
100 PUT31:
110 PUT22,10,27: PRINT "THE ORIENT EXPRESS, 1923"
120 PUT22,13,28: PRINT "(C) DAVID H. AHL, 1986"
125 PRINT
130 PRINT "PRESS ANY KEY TO CONTINUE."
139 CLOSE#6 :OPEN#6,6: REM THIS OPENS THE KEB DEVICE FOR INPUT NEEDED
140 GET#6,A: IF A=0 THEN 140
150 RANDOMIZE: PUT31
160 PRINT "THE MYSTERIOUS ARMS DEAL" : PRINT : GOSUB 1710
170 REM
180 REM INITIALIZATION
190 DIM C$(25), CN(25), CP(25), DA(25), HZ(25), LA$(25), LB$(25), ME(25), N$(25)
200 DIM TA(25), TD(25), CS(25), MB$(15), MD$(26)
210 GOSUB 1880 : REM READ DATA ABOUT JOURNEY SEGMENTS
220 GOSUB 2160 : REM READ STATEMENTS OF TRAVELERS
230 GOSUB 2430 : REM READ NAMES OF THOSE ON THE TRAIN
240 GOSUB 2530 : REM READ MENU SELECTIONS
250 GOSUB 2760 : REM SHUFFLE 24 INTEGERS FOR LATER USE
260 PRINT "PRESS ANY KEY TO CALL A TAXI"
261 GET#6,A: IF A=0 THEN GOTO261
270 REM
280 REM MAIN PROGRAM
290 FOR J = 1 TO 24 : REM ITERATE THROUGH LOCATIONS
300 PRINT : PRINT "FEBRUARY";DA(J) + 13 + HY;"1923" : REM PRINT DATE
310 TN = 18 - INT(27 * RND) : TB = TA(J) + TN : T = TB : IF J = 1 THEN GOTO450
320 GOSUB 3110 : PRINT " YOU HAVE ARRIVED AT ";LA$(J);", ";LB$(J);" AT"; : GOSUB
3060
330 IF TN > 1 THEN PRINT "JUST ";TN;" MINUTES LATE." : GOTO 360
340 IF TN < -1 THEN PRINT "ALMOST"; TN;" MINUTES EARLY." : GOTO 360
350 PRINT " RIGHT ON TIME!"
360 IF TB > TD(J) -2 THEN T = TB + 4 :GOTO 370
365 T = TD(J) : REM MAKE SURE DEPARTURE IS AFTER ARRIVAL
370 IF J = 24 THEN 3190 :GOTO 380
375 IF ME(J) < 4 THEN 400 : REM IS IT DAYTIME?
380 PRINT "ASLEEP IN YOUR COMPARTMENT, YOU BARELY NOTICE THAT THE"
390 PRINT "DEPARTURE WAS RIGHT ON TIME AT"; : GOSUB 3060 : GOSUB 2860 : GOTO 490
400 IF J = 23 THEN GOSUB 1340 : REM TIME TO IDENTIFY THE KILLER AND DEFECTOR?
410 PRINT "DEPARTURE IS AT"; : GOSUB 3060 : PRINT
420 PRINT "WOULD YOU LIKE TO GET OFF AND STRETCH YOUR LEGS":INPUT A$ : GOSUB 281
0
430 IF A = 1 THEN PRINT "OKAY, YOU STAY IN YOUR COMPARTMENT." : GOTO 470
440 PRINT "OKAY, BUT BE SURE NOT TO MISS THE TRAIN." : GOTO 470
450 PRINT "THE TAXI HAS DROPPED YOU AT VICTORIA STATION IN LONDON."
460 PRINT "THE ORIENT EXPRESS IS STANDING MAJESTICALLY ON TRACK 14."
470 PRINT : GOSUB 2860 : PRINT "ALL ABOARD";
480 GOSUB 2860 : PRINT " TRAIN IS LEAVING." : GOSUB 2860
490 GOSUB 2990 : REM TRAIN NOISES
500 GOSUB 2860 : IF J > 1 THEN GOTO570 : REM FIRST LEG OF TRIP?
510 X=3+INT(20*RND)
520 PRINT : PRINT "YOU SPEAK TO SOME OF THE PASSENGERS ";N$(X);","
530 PRINT N$(X + 1);", ";N$(X + 2);" AND OTHERS AND ASK THEM TO KEEP"
540 PRINT "THEIR EYES AND EARS OPEN AND TO PASS ANY INFORMATION NO"
550 PRINT "MATTER HOW TRIVIAL TO YOU IN COMPARTMENT 13. THE CHANNEL"
560 PRINT "CROSSING IS PLEASANT AND THE FIRST PART OF THE TRIP UNEVENTFUL."
570 IF J = 23 THEN GOSUB 1490 : REM TIME TO IDENTIFY THE KILLER AND DEFECTOR?
580 IF ME(J) > 0 AND ME(J) < 4 THEN ON ME(J) GOSUB 770, 720, 640 : REM MEALS
590 GOSUB 860 : REM TALK TO PASSENGERS
600 IF HZ(J) > 0 THEN ON HZ(J) GOSUB 970, 1110 : REM SNOW OR BANDITS ON THIS LEG ?
610 GOSUB 1220 : REM OTHER HAZARDS
620 NEXT J
630 REM
640 REM SUBROUTINE TO SERVE BREAKFAST
650 PRINT : PRINT "BREAKFAST IS NOW BEING SERVED IN THE RESTAURANT CAR."
660 PRINT "PRESS ANY KEY WHEN YOU'RE READY TO HAVE BREAKFAST."
670 GET#6,A: IF A=0 THEN GOTO670
671 PUT31: PUT 22,3,33: ?"BREAKFAST MENU"
680 FOR I = 1 TO 4 : X = 3 * (I - 1) + 1 + INT(3 * RND)
690 PUT22,4 + 3 * I, (80 - LEN(MB$(X))) / 2 : PRINT MB$(X) : NEXT I
700 PUT22,19,20 : PRINT MB$(13) : GOSUB 2950 : RETURN
710 REM
720 REM SUBROUTINE TO SERVE LUNCH
730 PRINT : PRINT "AN ENORMOUS BUFFET LUNCHEON HAS BEEN LAID OUT IN THE ";
740 PRINT "RESTAURANT CAR." : PRINT "PRESS ANY KEY WHEN YOU HAVE FINISHED.";
751 GET#6,A:IF A=0 THEN 751
756 PRINT "B-U-R-P !": RETURN
760 REM
770 REM SUBROUTINE TO SERVE DINNER
780 PRINT : PRINT "DINNER IS NOW BEING SERVED IN THE RESTAURANT CAR."
790 PRINT "PRESS ANY KEY WHEN YOU'RE READY TO HAVE DINNER."
801 GET#6,A: IF A=0 THEN 801
802 PUT31: PUT22,1,34 : PRINT "DINNER MENU"
810 FOR I = 1 TO 7 : X = 3 * (I - 1) + 1 + INT(3 * RND)
820 PUT22, 2 + 2 * I, (80 - LEN(MD$(X))) / 2 : PRINT MD$(X) : NEXT I
830 PUT22,18,24 : PRINT MD$(22) : PUT22,20,30 : PRINT MD$(23)
840 PUT22,22,32 : PRINT MD$(24) : GOSUB 2950 : RETURN
850 REM
860 REM SUBROUTINE TO HAVE CONVERSATION
865 IF CN(J)=0 THEN RETURN
870 FOR K = 1 TO CN(J) :REM ITERATE THROUGH CONVERSATIONS IN THIS TRIP SEGMENT
880 GOSUB 2890 : CM = CM + 1 : REM RING COMPARTMENT BUZZER AND OPEN DOOR
890 IF CP(CS(CM)) > 0 THEN X = CP(CS(CM)):GOTO 900
895 X = 3 + INT(23 * RND)
900 PRINT "STANDING THERE IS ";N$(X);", WHO TELLS YOU:" : X = CS(CM)
910 IF LEN(C$(X)) < 81 THEN PRINT C$(X) : GOTO 950 : REM'IF SHORT MESSAGE, PRINT IT
920 CS(RN) = CS(CM) : FOR KA = 79 TO 1 STEP -1
930 IF MID$(C$(X), KA, 1)=" " THEN GOTO 940:REM FIND A SPACE NEAR END OF LINE
935 NEXT KA :REM 'FIND A SPACE NEAR END OF LINE
940 PRINT LEFT$(C$(X), KA) : PRINT RIGHT$(C$(X), LEN(C$(X)) - KA)
950 NEXT K : RETURN
960 REM
970 REM SUBROUTINE FOR SNOW
980 X = RND : IF X > .65 THEN RETURN : REM 65% CHANCE OF SNOW
990 PRINT : PRINT "IT IS SNOWING HEAVILY ";
1000 IF X < .01 THEN 1030 : REM 1% CHANCE OF GETTING STUCK IN THE SNOW
1010 PRINT "BUT THE TRACKS HAVE BEEN CLEARED AND THE TRAIN"
1020 PRINT "WILL NOT BE DELAYED." : RETURN
1030 PRINT "AND THE TRAIN IS FORCED TO SLOW DOWN." : PRINT
1040 PRINT "OH NO! THE TRAIN IS COMING TO A STOP. LET'S HOPE THIS IS"
1050 PRINT "NOT A REPEAT OF THE TRIP OF JANUARY 29, 1929 WHEN THE ORIENT"
1060 PRINT "EXPRESS WAS STUCK IN SNOWDRIFTS FOR FIVE DAYS." : PRINT : GOSUB 2860
1070 PRINT "BUT IT LOOKS LIKE IT IS!" : GOSUB 2860
1080 PRINT "YOU ARE STRANDED FOR TWO DAYS UNTIL A SNOWPLOW CLEARS THE TRACK."
1090 PRINT "THE TRAIN IS NOW EXACTLY TWO DAYS BEHIND SCHEDULE." : HY = HY + 2 :
RETURN
1100 REM
1110 REM SUBROUTINE FOR BANDITS
1120 IF RND > .04 THEN RETURN : REM 4% CHANCE OF BANDITS
1130 IF HX = 1 THEN RETURN ELSE HX = 1 : REM ONLY ONE BANDIT ATTACK
1140 PRINT : PRINT "YOU ARE RUDELY AWAKENED FROM A DEEP SLEEP BY A LOUD NOISE"
1150 PRINT "AS THE TRAIN JERKS TO A HALT." : GOSUB 2890
1160 PRINT "YOU ARE SHOCKED TO SEE A BANDIT WAVING A GUN IN YOUR FACE."
1170 PRINT "HE DEMANDS THAT YOU GIVE HIM YOUR WALLET, JEWELRY, AND WATCH." : PRINT
1180 GOSUB 2860 : PRINT "THE BANDITS ARE OFF THE TRAIN IN A FEW MOMENTS WITH"
1190 PRINT "THEIR LOOT. THEY DISAPPEAR INTO THE FOREST. NO ONE"
1200 PRINT "WAS INJURED, AND THE TRAIN RESUMES ITS JOURNEY." : RETURN
1210 REM
1220 REM SUBROUTINE TO DEAL WITH MISCELLANEOUS HAZARDS
1230 IF RND > .02 THEN RETURN : REM 2% CHANCE OF DERAILMENT
1240 IF HW = 1 THEN RETURN
1245 HW = 1 : REM ONLY ONE DERAILMENT
1250 PRINT : PRINT "YOU HEAR A LOUD SCREECHING NOISE AS THE TRAIN COMES TO A"
1260 PRINT "CRASHING STOP. THE ENGINE, TENDER, AND FIRST COACH ARE"
1270 PRINT "LEANING AT A CRAZY ANGLE. PEOPLE ARE SCREAMING.":GOSUB 2860
1280 PRINT : PRINT "WHILE NOT AS BAD AS THE DERAILMENT AT VITRY-LE-FRANCOIS IN"
1290 PRINT "NOVEMBER 1911, THERE IS NO QUESTION THAT THE FRONT OF THE"
1300 PRINT "TRAIN HAS LEFT THE TRACK." : GOSUB 2860 : PRINT
1310 PRINT "YOU ARE STRANDED FOR EXACTLY ONE DAY WHILE THE TRACK IS"
1320 PRINT "REPAIRED AND A NEW LOCOMOTIVE OBTAINED." : HY = HY + 1 : RETURN
1330 REM
1340 REM SUBROUTINE TO IDENTIFY DEFECTOR AND KILLER
1350 PRINT : PRINT "THE TURKISH POLICE HAVE BOARDED THE TRAIN. THEY HAVE BEEN"
1360 PRINT "ASKED TO ASSIST YOU, BUT FOR THEM TO DO SO YOU WILL HAVE TO"
1370 PRINT "IDENTIFY THE KILLER (THE DEALER IN MACHINE GUNS) AND THE DEFECTOR"
1380 PRINT "(THE SCOTCH DRINKER) TO THEM. THE ARMS DEALERS ARE LINED"
1390 PRINT "UP AS FOLLOWS:" : PRINT : PRINT " (1) AUSTRIAN, (2) TURK, ";
1400 PRINT "(3) POLE, (4) GREEK, (5) RUMANIAN." : PRINT
1410 PRINT "WHO IS THE DEFECTOR (A NUMBER PLEASE)";:INPUT A1
1420 PRINT "AND WHO IS THE KILLER";:INPUTA2 : GOSUB 2860
1430 PRINT : PRINT "THE POLICE TAKE INTO CUSTODY THE MAN YOU IDENTIFIED AS THE"
1440 PRINT "KILLER AND PROVIDE A GUARD TO RIDE ON THE TRAIN WITH THE"
1450 PRINT "DEFECTOR. YOU RETURN TO YOUR COMPARTMENT, PRAYING THAT"
1460 PRINT "YOU MADE THE CORRECT DEDUCTIONS AND IDENTIFIED THE RIGHT MEN."
1470 PRINT : GOSUB 2860 : RETURN
1480 REM
1490 REM SUBROUTINE TO CHECK THE IDENTITIES
1500 IF A1 = A3 OR A1 = A4 THEN 1600 : REM DEFECTOR SAVED?
1510 PRINT : PRINT "YOU ARE SUDDENLY AWAKENED BY WHAT SOUNDED LIKE A GUNSHOT."
1520 PRINT "YOU RUSH TO THE DEFECTOR'S COMPARTMENT, BUT HE IS OKAY."
1530 PRINT "HOWEVER, ONE OF THE OTHER ARMS DEALERS HAS BEEN SHOT." : GOSUB 2860
1540 PRINT : PRINT "YOU REVIEW THE DETAILS OF THE CASE IN YOUR MIND AND REALIZE"
1550 PRINT "THAT YOU CAME TO THE WRONG CONCLUSION AND DUE TO YOUR MISTAKE"
1560 PRINT "A MAN LIES DEAD AT THE HANDS OF BANDITS. YOU RETURN TO YOUR"
1570 PRINT "COMPARTMENT AND ARE CONSOLED BY THE THOUGHT THAT YOU CORRECTLY"
1580 PRINT "IDENTIFIED THE KILLER AND THAT HE WILL HANG FOR HIS CRIMES."
1590 REM
1600 IF A2 = A4 THEN A5 = 1 : RETURN : REM KILLER IS STILL ON THE TRAIN
1610 GOSUB 2890 : PRINT "A MAN IS STANDING OUTSIDE. HE SAYS, 'YOU MADE A"
1620 PRINT "MISTAKE. A BAD ONE. YOU SEE, I AM THE MACHINE-GUN DEALER."
1630 IF A1<>A4 THEN 1660 : REM WRONGLY IDENTIFIED DEFECTOR AS KILLER?
1640 PRINT "MOREOVER, YOU INCORRECTLY IDENTIFIED THE MAN WHO WAS COOPERATING"
1650 PRINT "WITH YOU AS THE KILLER. SO THE STATE WILL TAKE CARE OF HIM. HA."
1660 PRINT : GOSUB 2860 : PRINT "HE DRAWS A GUN. BANG. YOU ARE DEAD."
1670 PRINT : PRINT "YOU NEVER KNOW THAT THE TRAIN ARRIVED AT 12:30, RIGHT ON"
1680 PRINT "TIME AT CONSTANTINOPLE, TURKEY." : GOSUB 2860 : GOSUB 2860
1690 PRINT : PRINT : GOTO 3190
1700 REM
1710 REM SUBROUTINE TO SET THE SCENARIO
1720 PRINT "IT IS FEBRUARY 1923. THE FOLLOWING NOTE IS RECEIVED AT"
1730 PRINT "WHITEHALL: 'IF YOU WILL FURNISH ME WITH A NEW IDENTITY AND A"
1740 PRINT "LIFETIME SUPPLY OF SCOTCH, I WILL GIVE UP MY LIFE OF ARMS DEALING"
1750 PRINT "AND WILL PROVIDE YOU WITH MUCH VALUABLE INFORMATION. I WILL BE"
1760 PRINT "ON THE ORIENT EXPRESS TONIGHT. BUT YOU MUST CONTACT ME BEFORE"
1770 PRINT "THE TRAIN REACHES UZUNKOPRU OR THAT SWINE DEALER OF MAXIM MACHINE"
1780 PRINT "GUNS WILL HAVE ME KILLED BY BANDITS LIKE HE DID TO BARON WUNSTER"
1790 PRINT "LAST MONTH.' THE NOTE IS NOT SIGNED."
1800 PRINT "YOU, A BRITISH AGENT, ARE ASSIGNED TO TAKE THE TRAIN, RESCUE"
1810 PRINT "THE DEFECTOR, AND ARREST THE KILLER."
1820 PRINT "YOU KNOW THERE ARE FIVE NOTORIOUS ARMS DEALERS OF DIFFERENT"
1830 PRINT "NATIONALITIES OPERATING IN EUROPE UNDER AN UNEASY TRUCE AS EACH"
1840 PRINT "DEALS IN A DIFFERENT KIND OF WEAPON. BUT IT IS OBVIOUS THAT THE TRUCES ENDED."
1850 A4 = A5 : PRINT : PRINT
1860 PRINT "PRESS ANY KEY TO CALL A TAXI"
1862 GET#6,a:IF a=0 THEN GOTO1862
1870 RETURN
1880 REM SUBROUTINE TO READ MEALS, CONVERSATIONS, HAZARDS, DAY, TIMES, LOCATIONS
1890 FOR I = 1 TO 24 : READ X, ME(I), CN(I), HZ(I), DA(I), TA(I), TD(I), LA$(I),
LB$(I)
1900 NEXT i:RETURN
1910 DATA 1, 0, 0, 0, 1, 0, 1430, "LONDON", "ENGLAND"
1920 DATA 2, 1, 2, 0, 1, 1855, 1919, "CALAIS", "FRANCE"
1930 DATA 3, 0, 1, 0, 1, 2233, 2253, "PARIS (NORD)", "FRANCE"
1940 DATA 4, 4, 0, 0, 1, 2316, 2350, "PARIS (LYON)", "FRANCE"
1950 DATA 5, 4, 0, 1, 2, 600, 620, "VALLORBE", "SWITZERLAND"
1960 DATA 6, 0, 1, 0, 2, 700, 707, "LAUSANNE", "SWITZERLAND"
1970 DATA 7, 3, 1, 1, 2, 732, 734, "MONTREUX", "SWITZERLAND"
1980 DATA 8, 0, 1, 1, 2, 919, 927, "BRIG", "SWITZERLAND"
1990 DATA 9, 0, 3, 0, 2, 1005, 1025, "DOMODOSSOLA", "ITALY"
2000 DATA 10, 2, 2, 0, 2, 1223, 1320, "MILAN", "ITALY"
2010 DATA 11, 1, 2, 0, 2, 1705, 1730, "VENICE (S. LUCIA)", "ITALY"
2020 DATA 12, 0, 1, 0, 2, 1954, 2014, "TRIESTE", "(FREE STATE)"
2030 DATA 13, 0, 1, 0, 2, 2044, 2110, "OPICINA", "ITALY"
2040 DATA 14, 0, 2, 0, 2, 2119, 2225, "SEZANA", "SLOVENIA"
2050 DATA 15, 4, 0, 0, 3, 21, 107, "LJUBLJANA", "SLOVENIA"
2060 DATA 16, 4, 0, 0, 3, 310, 330, "ZAGREB", "CROATIA"
2070 DATA 17, 3, 2, 0, 3, 900, 956, "BELGRADE", "SERBIA"
2080 DATA 18, 2, 1, 0, 3, 1334, 1356, "CRVENI KRST", "SERBIA"
2090 DATA 19, 0, 2, 0, 3, 1555, 1634, "CARIBROD", "SERBIA"
2100 DATA 20, 1, 2, 0, 3, 1856, 1935, "SOFIA", "BULGARIA"
2110 DATA 21, 4, 0, 2, 4, 45, 120, "SVILENGRAD", "BULGARIA"
2120 DATA 22, 4, 0, 2, 4, 406, 445, "PITHION", "GREECE"
2130 DATA 23, 3, 0, 3, 4, 505, 545, "UZUNKOPRU", "TURKEY"
2140 DATA 24, 0, 0, 0, 4, 1230, 0, "CONSTANTINOPLE", "TURKEY"
2150 REM
2160 REM SUBROUTINE TO READ STATEMENTS OF TRAVELERS
2170 FOR I = 1 TO 24 : READ CS(I), CP(I), C$(I) : NEXT I : RETURN
2180 DATA 1, 0, "I'VE HEARD THEY ALL HAVE DIFFERENT COLOR CHALETS ON A NORTH-SOU
TH RIDGE IN THE TYROL REGION."
2190 DATA 2, 0, "THE AUSTRIAN SAID HE LIKES THE LOOK OF NATURAL WOOD AND WOULD N
EVER PAINT HIS CHALET."
2200 DATA 3, 0, "THEY GAVE THE WAITER A DIFFICULT TIME. THE TURK ORDERED BEER AN
D THE OTHER FOUR ALL ORDERED DIFFERENT DRINKS."
2210 DATA 4, 0, "THE GREEK TOLD ME HE HUNTS DEER, BUT HE NEVER HUNTS WITH ANY OF
THE OTHERS BECAUSE THEY ALL HUNT DIFFERENT ANIMALS."
2220 DATA 5, 1, "MY BROTHER DELIVERED A CASE OF KIRSCH TO THE GREEN CHALET. HE R
EMEMBERS IT BEING JUST SOUTH OF THE GAUDY RED CHALET."
2230 DATA 6, 0, "THE POLE ASKED MECAN YOU IMAGINE THAT?IF I WANTED TO BUY ANY HOWITZERS."
2240 DATA 7, 2, "ONE OF THEM ASKED ME TO COOK SOME PHEASANT THAT HE SHOT. HE SAI
D THAT I SHOULD COME TO THE YELLOW CHALET."
2250 DATA 8, 1, "ONE TIME MY BROTHER SAID HE DELIVERED A CASE OF COGNAC TO THE MIDDLE CHALET."
2260 DATA 9, 0, "THE RUMANIAN SAID HE HAD THE SHORTEST DISTANCE TO DRIVE FROM HI
S CHALET TO THE RAILROAD STATION AT MUNICH."
2270 DATA 10, 0, "ONE OF THEM BRAGGED THAT HIS MILITARY RIFLES WERE SO ACCURATE
THAT HE BAGGED A FOX WITH ONE OF THEM."
2280 DATA 11, 0, "THE MAN WHO HUNTS WILD BOAR SAID THAT THE PISTOL DEALER WHO LI
VES IN THE CHALET NEXT TO HIS OFTEN GIVES LOUD PARTIES."
2290 DATA 12, 0, "THE PHEASANT HUNTER COMPLAINED THAT THE ARMS DEALER IN THE CHA
LET NEXT TO HIS MAKES FAR TOO MUCH NOISE TESTING HIS MORTARS."
2300 DATA 13, 0, "THE GIN DRINKER BRAGGED THAT HE SHOT SIXTY WARTHOGS ON A SINGL
E DAY LAST AUGUST."
2310 DATA 14, 0, "THE RUMANIAN SAID HE LOOKS OUT ON A BLUE CHALET."
2320 DATA 15, 0, "THE COGNAC DRINKER BRAGGED THAT HE IS THE BEST HUNTER AND CAN
DRINK MORE THAN ALL OF THE REST OF THEM COMBINED."
2330 DATA 16, 0, "THE ONE CARRYING THE PISTOL SAID HE THINKS THE BOAR'S HEAD OVE
R HIS NEIGHBOR'S DOORWAY IS REVOLTING."
2340 DATA 17, 0, "ONE OF THEM SAID THAT ONE DAY HE'D LIKE TO LOB A MORTAR SHELL
AT THE STRING OF PHEASANTS DRYING IN HIS NEIGHBOR'S YARD."
2350 DATA 18, 0, "THE KIRSCH DRINKER SAID HE LOVED THE ROAST CHICKEN HE HAD TO EAT LAST NIGHT."
2360 DATA 19, 0, "THE ONE CARRYING THE PISTOL HAD A SECOND HELPING OF PIE."
2370 DATA 20, 0, "ONE COMMENTED THAT HIS BEEF DINNER WASN'T NEARLY AS GOOD AS THE BOAR THAT HE SHOT LAST WEEK."
2380 DATA 21, 0, "THE POLE ASKED FOR MORE SOUP."
2390 DATA 22, 0, "THE ONE EATING ALL THE CHEESE MUMBLED THAT IT WAS THE SAME COL
OR AS HIS CHALET."
2400 DATA 23, 0, "THE RUMANIAN AND AUSTRIAN GOT COMPLETELY DRUNK LAST NIGHT."
2410 DATA 24, 0, "I'D LIKE TO VISIT THE BLUE CHALET. THE OWNER IS SAID TO SERVE
EXCELLENT LOBSTER."
2420 REM
2430 REM SUBROUTINE TO READ THE NAMES OF THOSE ON THE TRAIN
2440 FOR I = 1 TO 25 : READ N$(I) : NEXT I : RETURN
2450 DATA "R. BRUNDT (A WAITER)", "C. D'ARCY (A CHEF)"
2460 DATA "HERBERT HOOVER", "BARON ROTHSCHILD", "GUIDO FAMADOTTA", "GUSTAV MAHLER"
2470 DATA "ROBERT BADEN-POWELL", "FRITZ KREISLER", "DAME MELBA", "GERALD MURPHY"
2480 DATA "CALOUSTE GULBENKIAN", "CAPTAIN G.T. WARD", "SIR ERNEST CASSEL"
2490 DATA "MAJOR CUSTANCE", "F. SCOTT FITZGERALD", "ELSA MAXWELL", "MATA HARI"
2500 DATA "CLAYTON PASHA", "ARTURO TOSCANINI", "MAHARAJAH BEHAR", "LEON WENGER"
2510 DATA "SARAH BERNHARDT", "ARTHUR VETTER", "ISADORA DUNCAN", "DAVID K.E. BRUCE"
2520 REM
2530 REM SUBROUTINE TO READ MENUS
2540 FOR I = 1 TO 13 : READ MB$(I) : NEXT I : REM BREAKFAST SELECTIONS
2550 FOR I = 1 TO 26 : READ MD$(I) : NEXT I : REM DINNER SELECTIONS
2560 RETURN
2570 DATA "VARIETE JUS DE FRUITS", "PRUNES MACEREES DANS LE VIN"
2580 DATA "DEMI PAMPLEMOUSE", "TROIS OEUFS SUR LE PLAT", "OEUFS POCHES"
2590 DATA "OMELETTE AUX CHAMPIGNONS", "TRANCHES DE PAIN BEUREES ET CONFITUREES"
2600 DATA "GALETTES", "POMMES-FRITES", "PATISSERIES", "CROISSANTS", "YOGURT"
2610 DATA "CAFE, THE, LAIT, VIN, EAU MINERALE"
2620 DATA "HUITRES DE BEERNHAM", "CANTALOUP GLACE AU MARSALE"
2630 DATA "COMPOTE DES TOMATES FRAICHES", "POTAGE REINE"
2640 DATA "LA NATTE DE SOLE AU BEURRE", "TRUITE DE RIVIERE MEUNIERE"
2650 DATA "POULET DE GRAIN GRILLE A DIABLE", "ROTI DE VEAU A L'OSILLE"
2660 DATA "TRUITE SAUMONEE A LA CHAMBORD", "CHAUD-FROID DE CANETON"
2670 DATA "CHAUDFROIX DES LANGOUSTE A LA PARISIENNE"
2680 DATA "LES NOISETTES DE CHEVREUIL RENAISSANCE", "BECASSES A LA MONACO"
2690 DATA "POINTES D'ASPERGE A LA CREME", "PARFAIT DE FOIES GRAS"
2700 DATA "SALADE CATALANE", "TRUFFES AU CHAMPAGNE"
2710 DATA "TAGLIATELLE DE CAROTTES ET COURGETTES", "SOUFFLE D'ANISETTE"
2720 DATA "CREME DE CARAMEL BLOND", "SORBET AUX MURES DE FRAMBOISIER"
2730 DATA "LA SELECTION DU MAITRE FROMAGER", "CORBEILLE DE FRUITS"
2740 DATA "LES MIGNARDISES", "SELECTION DU VINS ET LIQUORS","POUTINE RAPAIS"
2750 REM
2760 REM SUBROUTINE TO SHUFFLE 24 INTEGERS
2770 FOR I = 1 TO 23
2780 K = I + INT((25 - I) * RND) : X = CS(I) : CS(I) = CS(K) : CS(K) = X : NEXT I
2790 RETURN
2810 REM
2820 IF LEFT$(A$, 1) = "Y" OR LEFT$(A$, 1) = "y" THEN A = 0 : RETURN
2830 IF LEFT$(A$, 1) = "N" OR LEFT$(A$, 1) = "n" THEN A = 1 : RETURN
2840 STOP:PRINT "PLEASE ENTER Y FOR 'YES' OR N FOR 'NO.' WHICH IS IT":INPUT A$ :
GOTO 2810
2850 REM
2860 REM SUBROUTINE CREATES A SHORT PAUSE
2870 FOR X = 1 TO 2500 : NEXT X : RETURN
2880 REM
2890 REM SUBROUTINE TO RING BUZZER AND OPEN DOOR
2900 PRINT : PRINT "YOUR COMPARTMENT BUZZER RINGS"
2920 PRINT "PRESS ANY KEY TO OPEN THE DOOR."
2930 GET#6,A: IF A=0 THEN GOTO2930
2931 RETURN
2940 REM
2950 REM SUBROUTINE TO FINISH EATING
2960 PUT22,24,18 : PRINT "PRESS ANY KEY WHEN YOU HAVE FINISHED EATING";
2970 A3 = A3 + 5 * (J + 1) -(18+43):a4=a3-1
2972 GET#6,A: IF A=0 THEN 2972
2975 PUT31: RETURN
2980 REM
2990 REM SUBROUTINE TO PRODUCE TRAIN NOISES
3000 PRINT : PRINT "CLACKETY CLACKCLACKETY CLACKCLACKETY CLACK"
3010 IF RND > .5 THEN RETURN
3015 FOR KA = 6 TO 1 STEP -1
3020 FOR I = 1 TO 4 :?"TU";: FOR K = 1 TO 180 : NEXTk: NEXTI
3030 IF KA = 4 THEN GOSUB 3110
3040 FOR K = 1 TO 50 + KA * 120 : NEXTK: NEXTKA:RETURN
3050 REM
3060 REM SUBROUTINE TO PRINT TIME
3070 T = T + 10000 : T$ = STR$(T) : IF VAL(RIGHT$(T$, 2)) > 59 THEN T = T + 40
3080 T$ = STR$(T) : PRINT " ";MID$(T$, 3, 2);":";RIGHT$(T$, 2);" ";
3090 RETURN
3100 REM
3110 REM SUBROUTINE TP BLOW TRAIN WHISTLE
3120 IF RND >.5 THEN RETURN
3130 FOR K=1 TO 1400: NEXT K:?"TUUT";
3140 FOR K=1 TO 200:NEXT K:RETURN
3150 REM
3160 REM ERROR-HANDLING SUBROUTINE
3170 A5 = ERR : RESUME NEXT
3180 REM
3190 REM END OF JOURNEY
3200 PRINT : PRINT "YOUR JOURNEY HAS ENDED. GEORGES NAGELMACKERS AND THE"
3210 PRINT "MANAGEMENT OF CIE. INTERNATIONALE DES WAGONS-LITS "
3220 PRINT "HOPE YOU ENJOYED YOUR TRIP ON THE ORIENT EXPRESS, THE"
3230 PRINT "MOST FAMOUS TRAIN IN THE WORLD." : PRINT : PRINT
3240 IF A5<>1 THEN 3310 : X = 0
3250 PRINT "WHITEHALL TELEGRAPHS CONGRATULATIONS FOR IDENTIFYING BOTH"
3260 PRINT "THE KILLER AND DEFECTOR CORRECTLY." : GOSUB 2860 : GOSUB 2860
3270 FOR I = 1 TO 25 : FOR K = 1 TO 100 : NEXT K : PUT22,15,30 : PRINT X$
3280 IF X = 0 THEN X$ = "CONGRATULATIONS !" : X = 1 : GOTO 3300
3290 X$ = " " : X = 0 : REM 'X$ = 17 SPACES TO ERASE CONGRATULATIONS
3300 NEXT I : PRINT : PRINT : PRINT
3310 PRINT "WOULD YOU LIKE TO RIDE AGAIN":INPUT A$ : GOSUB 2810
3320 IF A = 0 THEN PRINT "OKAY. GOOD JOURNEY!" : GOSUB 2860 : RUN
3330 PRINT "OKAY. SO LONG FOR NOW." : GOSUB 2860 : PUT31 : END

User avatar
jgerrie
Posts: 280
Joined: Sat Aug 17, 2013 1:25 pm
Location: Nova Scotia
Contact:

Re: Another Classic Ported to TRS-80 MC-10

#38 Post by jgerrie » Fri Apr 01, 2016 5:05 am

Very nice :D

User avatar
jgerrie
Posts: 280
Joined: Sat Aug 17, 2013 1:25 pm
Location: Nova Scotia
Contact:

Re: Another Classic Ported to TRS-80 MC-10

#39 Post by jgerrie » Tue Apr 26, 2016 4:30 am

Okay I've been working on Trek Adventure 2/Galaxy Trek Adventure #2 by Howard Batie. I've condensed the code so it fits (I hope) into a regular MC-10. There are three files: GALSTART, GALTREK1 and GALTREK2
Run GALSTART for instructions for the game
GALTREK1 to start the game (this is the main program)
then play GALTREK2 (a data file used by GALTREK1)

Vid:
https://youtu.be/jqIFYE7zUtE
Download of Emulator and the three files (in the JimG directory)
http://faculty.cbu.ca/jgerrie/Home/VMC10_073D.zip

Colin Appleby
Posts: 93
Joined: Wed Mar 16, 2016 10:05 pm

Re: Another Classic Ported to TRS-80 MC-10

#40 Post by Colin Appleby » Tue Apr 26, 2016 1:38 pm

Can you publish the listing of Planet of Death so I can convert it to NewBrain Basic. Thanks.

User avatar
jgerrie
Posts: 280
Joined: Sat Aug 17, 2013 1:25 pm
Location: Nova Scotia
Contact:

Re: Another Classic Ported to TRS-80 MC-10

#41 Post by jgerrie » Wed Apr 27, 2016 7:50 am

It's here:

https://github.com/jggames/trs80mc10/tr ... ogress/POD

POD.6.TXT is the most up-to-date version, ignore the rest.
Colin Appleby wrote:Can you publish the listing of Planet of Death so I can convert it to NewBrain Basic. Thanks.

User avatar
jgerrie
Posts: 280
Joined: Sat Aug 17, 2013 1:25 pm
Location: Nova Scotia
Contact:

Re: Another Classic Ported to TRS-80 MC-10

#42 Post by jgerrie » Sun Jun 05, 2016 1:52 am

Converted an adventure game "Success Mansion" written by Paul Ruby Jr in 1986 for the TRS-80 Coco. It was designed to support the Tandy Speech/Sound Pak but I have removed all those elements. The game must be loaded in two parts, the main program SUCCESS1.C10 and then a data file SUCCESS2.C10. I believe it was a Type-In from some Coco magazine in the 1980s.
success.png
success.png (5.16 KiB) Viewed 3136 times

User avatar
jgerrie
Posts: 280
Joined: Sat Aug 17, 2013 1:25 pm
Location: Nova Scotia
Contact:

Re: Another Classic Ported to TRS-80 MC-10

#43 Post by jgerrie » Wed Jun 08, 2016 11:13 am

I have ported (and corrected misspellings) "An Unexplored Mansion" from the Coco to MC-10 BASIC.
umansion.png
umansion.png (3.9 KiB) Viewed 3127 times
Map to follow.

User avatar
jgerrie
Posts: 280
Joined: Sat Aug 17, 2013 1:25 pm
Location: Nova Scotia
Contact:

Re: Another Classic Ported to TRS-80 MC-10

#44 Post by jgerrie » Sat Jun 11, 2016 12:57 pm

Here's a map to UMansion:
UMansionMap.png
UMansionMap.png (26.31 KiB) Viewed 3120 times

User avatar
jgerrie
Posts: 280
Joined: Sat Aug 17, 2013 1:25 pm
Location: Nova Scotia
Contact:

Re: Another Classic Ported to TRS-80 MC-10

#45 Post by jgerrie » Mon Jun 13, 2016 2:31 am

I have ported the Sinclair Spectrum game "Time Switch" (AKA) "Time Slider" by Colin Carruthers and published in Your Computer magazine August 1983.
slider.png
slider.png (3.02 KiB) Viewed 3109 times
Source can be found here:
https://github.com/jggames/trs80mc10/tr ... cts/Slider

Post Reply