Source for "Trek adventure" Robert J. Retelle

Games for Spectrum, C64, Amstrad, Amiga, Apple ][ and the rest of the 8-bit and 16-bit platforms. Pleas for help, puzzles, bug reports etc.

Moderator: Alastair

Message
Author
User avatar
jgerrie
Posts: 280
Joined: Sat Aug 17, 2013 1:25 pm
Location: Nova Scotia
Contact:

Source for "Trek adventure" Robert J. Retelle

#1 Post by jgerrie » Fri Jun 19, 2015 12:50 am

Anyone out there know where I can find the source for "Trek adventure" by Robert J. Retelle?

User avatar
Garry
Posts: 468
Joined: Sun Oct 28, 2012 11:43 am
Location: Sydney, Australia
Contact:

Re: Source for "Trek adventure" Robert J. Retelle

#2 Post by Garry » Fri Jun 19, 2015 6:38 am

According to the database, it's available for the C64, TRS-80, CoCo, TI-99/4A and OSI/Compukit. You can get the C64 version from Gamebase 64 (http://www.gb64.com/game.php?id=11812). I haven't been able to find the others. I'd particularly like to find the TRS-80 and CoCo versions. I imagine that this would also be your preferred option.

User avatar
jgerrie
Posts: 280
Joined: Sat Aug 17, 2013 1:25 pm
Location: Nova Scotia
Contact:

Re: Source for "Trek adventure" Robert J. Retelle

#3 Post by jgerrie » Sat Jun 20, 2015 1:49 am

Yes Coco would be preferred. Or OSI because must of its BASIC programs come in the form of straight ASCII. Any chance you know how to get the Commodore into ASCII format?
Garry wrote:According to the database, it's available for the C64, TRS-80, CoCo, TI-99/4A and OSI/Compukit. You can get the C64 version from Gamebase 64 (http://www.gb64.com/game.php?id=11812). I haven't been able to find the others. I'd particularly like to find the TRS-80 and CoCo versions. I imagine that this would also be your preferred option.

User avatar
Garry
Posts: 468
Joined: Sun Oct 28, 2012 11:43 am
Location: Sydney, Australia
Contact:

Re: Source for "Trek adventure" Robert J. Retelle

#4 Post by Garry » Sat Jun 20, 2015 5:16 am

The conversion process is a bit complicated to explain, so here's the ASCII file as an attachment. There are a few special characters at lines 5, 75, 365, 390 and 440, but you can replace them with the equivalent BASIC commands. I'm not a C64 user, but I think the first special character clears the screen and the remainder do a line feed. Other than that, the code looks very plain, so I don't think you'll have any trouble porting it to the MC10.

User avatar
jgerrie
Posts: 280
Joined: Sat Aug 17, 2013 1:25 pm
Location: Nova Scotia
Contact:

Re: Source for "Trek adventure" Robert J. Retelle

#5 Post by jgerrie » Sat Jun 20, 2015 1:14 pm

Super. Thanks very much. I had managed to get XVice, and even load it, but was having trouble trying to print it out to a file (unlike the coco, C64 doesn't have a nice LLIST command).
Garry wrote:The conversion process is a bit complicated to explain, so here's the ASCII file as an attachment. There are a few special characters at lines 5, 75, 365, 390 and 440, but you can replace them with the equivalent BASIC commands. I'm not a C64 user, but I think the first special character clears the screen and the remainder do a line feed. Other than that, the code looks very plain, so I don't think you'll have any trouble porting it to the MC10.

User avatar
jgerrie
Posts: 280
Joined: Sat Aug 17, 2013 1:25 pm
Location: Nova Scotia
Contact:

Re: Source for "Trek adventure" Robert J. Retelle

#6 Post by jgerrie » Sat Jun 20, 2015 1:16 pm

Now I should also ask. Has anyone completed this game? Walkthrough?

User avatar
Garry
Posts: 468
Joined: Sun Oct 28, 2012 11:43 am
Location: Sydney, Australia
Contact:

Re: Source for "Trek adventure" Robert J. Retelle

#7 Post by Garry » Sat Jun 20, 2015 1:27 pm

There used to be one on the archive, but it looks like it's gone walkabout. Try the solution attached. I can't guarantee that it will work, as I haven't played the game myself, but give it a try.

User avatar
Garry
Posts: 468
Joined: Sun Oct 28, 2012 11:43 am
Location: Sydney, Australia
Contact:

Re: Source for "Trek adventure" Robert J. Retelle

#8 Post by Garry » Sat Jun 20, 2015 1:47 pm

Oh, just for future reference, if you're using Windows, there's a neat C64 tool called DirMaster.exe. You can download it from http://style64.org/dirmaster. This allows you to create an ASCII text file as follows:

Open DirMaster.
Choose Disk > Open.
Select file type (typically *.d64 for disk, *.t64 for cassette).
Navigate to the disk or cassette file containing your BASIC program.
Double-click on it (or select it and click Open).
When the disk or cassette directory is displayed, right-click on the BASIC file that you want to convert and choose View file > BASIC.
When the BASIC listing is displayed, right-click on it and choose Export.
Select the file type of PETSCII (*.seq).
Select the Export as BasText check box.
Navigate to where you want to save it.
Enter the file name.
Click Save.
Hey presto. One C64 BASIC program saved as an ASCII text listing. Optionally, rename the .seq file once saved.

There may be other tools that do the same thing, but this is the one that I used.

User avatar
Alex
Posts: 958
Joined: Tue Oct 24, 2006 10:45 pm
Location: Netherlands

Re: Source for "Trek adventure" Robert J. Retelle

#9 Post by Alex » Sat Jun 20, 2015 8:55 pm

jgerrie wrote:unlike the coco, C64 doesn't have a nice LLIST command).
After loading the basic program the following commands will do the trick:

OPEN 4,4
CMD 4,”name”
LIST
PRINT#4
CLOSE 4


Garry, thanks for mentioning the tool. It does have some other interesting features.

User avatar
jgerrie
Posts: 280
Joined: Sat Aug 17, 2013 1:25 pm
Location: Nova Scotia
Contact:

Re: Source for "Trek adventure" Robert J. Retelle

#10 Post by jgerrie » Sun Jun 21, 2015 12:31 am

Thanks folks for all the help, especially all the stuff for dealing with Commodore BASIC. I was able to convert the source so it runs on MC-10, Coco and Dragon. And the walkthrough worked with no problems. Here's the proof:
trekadvWIN.png
trekadvWIN.png (17.95 KiB) Viewed 4302 times

Colin Appleby
Posts: 93
Joined: Wed Mar 16, 2016 10:05 pm

Re: Source for "Trek adventure" Robert J. Retelle

#11 Post by Colin Appleby » Sun Oct 16, 2016 9:54 pm

Is the Trek Adventure listing download correct for the DATA statements in lines 1280 to 1712. What are the extra , , for in the DATA statements.

I get an Error 45 at line 920 FORI=1TO50 when I run the program. Any help would be appreciated. Thanks

Regards

Colin

Colin Appleby
Posts: 93
Joined: Wed Mar 16, 2016 10:05 pm

Re: Source for "Trek adventure" Robert J. Retelle

#12 Post by Colin Appleby » Sun Oct 16, 2016 10:03 pm

I forgot to say that Error 45 is "Syntax error in FOR or NEXT Statement (wrong nesting)" on my Newbrain system that I am converting the program onto.

Regards

User avatar
jgerrie
Posts: 280
Joined: Sat Aug 17, 2013 1:25 pm
Location: Nova Scotia
Contact:

Re: Source for "Trek adventure" Robert J. Retelle

#13 Post by jgerrie » Sun Oct 23, 2016 3:19 am

Colin,

Don't see line 45 in my version: https://github.com/jggames/trs80mc10/bl ... EKADV4.TXT

The commas without anything between them are read as zeros between the commas by Microsoft Basics. So DATA,,,
is equivalent to DATA0,0,0,0

Jim
Colin Appleby wrote:I forgot to say that Error 45 is "Syntax error in FOR or NEXT Statement (wrong nesting)" on my Newbrain system that I am converting the program onto.

Regards

Colin Appleby
Posts: 93
Joined: Wed Mar 16, 2016 10:05 pm

Source for "Trek adventure" Robert J. Retelle now on NewBrai

#14 Post by Colin Appleby » Fri Nov 11, 2016 3:41 pm

I finally converted the "Trek adventure" to the NewBrain computer and it runs great. Thanks Jim G.
1 PUT31:CLEAR:GOTO7
2 C1=1:CC=32
3 IFMID$(M$,CC,1)<>""ANDMID$(M$,CC,1)<>" "THENCC=CC-1:GOTO3
5 PRINTMID$(M$,C1,CC-C1):C1=CC+1:CC=C1+31:IFC1<=LEN(M$)THEN3
6 RETURN
7 PUT31:PRINT" T R E K A D V E N T U R E"
8 GOSUB900:L=9:M=L:V=28:T=2:U=4:GOSUB195:GOTO365
9 PRINT:D=D-1:T=T-1:IFT<0THENU=U-1:T=59:IFU<0THEN850
50 O=O-1:IFO<6ANDO>0THENM$="OXYGEN LOW!"+STR$(O)+" MINUTES REMAINING":GOSUB2
55 IFO=0THENPRINT"OUT OF AIR!":GOTO845
60 IFL(4)>-1ANDL(5)>-1ANDZ=1THEN840
65 IF(L=11ORL=12)ANDNOTL(6)THEN830
75 PRINT"YOUR COMMAND":INPUT Z$:IFZ$="LOOK"THENZ$="LOOK AROUND"
76 A$=LEFT$(Z$,2):IFLEN(Z$)=0THEN75
80 FORI=1TO22:PRINT"-";:NEXTi:PRINT:IFA$="IN"THENJ=1:GOTO170
85 IFA$="FI"OR(A$="RE"ANDL=12)ORA$="PR"THENA$="DR"
86 IFA$="GE"THENA$="TA"
88 IFA$="WE"THENA$="PU"
90 IFA$="BL"THENA$="SH"
95 FORI=LEN(Z$)TO1STEP-1:IFMID$(Z$,I,1)=" "THEN100
96 NEXT i:GOTO 690
100 B$=MID$(Z$,I+1,2):IFB$="ID"THENB$="BA"
105 IFA$="PL"ANDB$="TA"THEN740
110 IFA$="PU"ANDB$="BU"ANDL=8THEN730
115 IFA$="CL"ANDB$="DO"THEN860
120 FORJ=1TOLEN(W$)STEP2:IFA$=MID$(W$,J,2)THENF=(J+1)/2:GOTO130
125 NEXTj:GOTO690
130 FORJ=1TOLEN(O$)STEP2:IFB$=MID$(O$,J,2)THENS=(J+1)/2:GOTO140
135 NEXTj:GOTO690
140 ON(F)GOTO220,150,560,300,475,585,620,620,620
145 IFA$="CH"THEN2000
150 IF(S=11)AND(L(5)=L)THENS=12
151 IF(S>V)THEN780
152 IF(S=7)AND(L(1)=L)THEN155
153 IFS<6THEN780
154 IF(L(S-7)<>L)THEN780
155 IFC=6OR(C=4AND(L(4)=-1ORL(5)=-1))THEN785
160 IFL(4)=L(5)ANDL=11THENS=12
165 L(S-7)=0:C=C+1:GOTO9
170 PRINT"YOU ARE CARRYING ":FORI=1TO21:IFL(I)=0THENPRINTO$(I+7):J=0
175 NEXTi:IFJ<>0THENPRINT"NOTHING"
180 FORI=4TO6:IFNOTL(I)THENNEXTi:GOTO9
185 PRINT:PRINT"YOU'RE WEARING-":FORI=4TO6:IFL(I)=-1THENPRINTO$(I+7)
190 NEXTi:GOTO9
195 O$="NOSOEAWEUPDOOUPHKLUNSPSPBOFLSHSEVABRPITRHASCWRBAPETAHAXX"
197 O$=O$+"VAMIVIENPAPOEQLOCEBUREPASTCRDOLOARDOTUTEVEWI"
205 W$="GOTADRLOOPSHPURE":RETURN
220 X=0:IFS=47AND(L=9ORL=23ORL=16)THENN=L:L=14:GOTO276
225 IFS=7ANDL=10THENL=11:GOTO276
230 IFS=5ANDL=11THENL=12:GOTO276
235 IFS=6AND(L=11ORL=12)THENL=L-1:GOTO276
240 IFS=6ANDD=-1THENL=E:GOTO276
245 IF(S=49ANDL<9)OR(L=13ANDD<-1)THEN720
250 M=L:IFL<>14THEN280
252 IFS>7THEN780
255 IFS<5THENM$=O$(47)+" BLOCKED "+O$(S):GOSUB2:GOTO9
260 IFS=7THENL=N:M=L:GOTO365
265 IF(S=5ANDN=23)OR(S=6ANDN=9)THENN=16:GOTO275
270 N=23:IFS=5THENN=9
275 GOTO365
276 M=L:GOTO365
280 M=L:IFS>4THEN780
285 IFP(L,S)>0THENL=P(L,S):M=L:GOTO365
290 GOTO780
300 IFS=45THEN365
305 IFS=39ANDL=8THEN755
310 IFL(4)=L ANDS=11THENO$(11)=O$(0)
315 IFL(5)=L ANDS=11THENO$(12)=O$(0)
320 IFS=50ANDX<>0THENGOSUB810
325 IFS=20ANDL(13)=0THEN685
330 IFS=33ANDL=9THENL(19)=L
335 IFS=34ANDL=9THEN680
340 IF(S=10)AND(L(3)=L)THENL(21)=L
345 IFB$<>"PO"THEN385
350 IFL(3)=L THENL(17)=L:L(18)=L:L(21)=50:GOTO385
355 IF(L(4)>0)AND(L(4)<>L)AND(L(5)<>L)ANDL(5)>0)THEN9
360 O$(22)="PHILLIPS SCREWDRIVER":L(15)=LW=1:GOTO385
365 J=0:M$="YOU ARE ":IFL>14THENM$=M$+"IN A CORRIDOR":GOTO375
370 M$=M$+D$(L)
375 GOSUB2:IFL=9ORL=23ORL=16THENL(40)=L
380 IF(L>9ANDL<13)THENL(34)=L
385 IFS=48THEN685
390 PRINT"YOU CAN SEE--":IFS=30ANDL=1THEN711
395 IF(M<>L)AND(M<15)THENM$=D$(M):GOSUB2
405 IFS=31THENM$="STARS AND A VERY CLOSE PLANET!":GOSUB2:GOTO9
410 L(39)=50:FORI=1TO4:IFP(L,I)<0THENL(39)=L
415 NEXTi:IF(L>3ANDL<8)ORL=23ORL=10ORL=22ORL=8THENX=1
420 FORI=1TO40
425 IF(L(I)=M)ANDLEN(M$)<245THENM$=O$(I+7):GOSUB2:J=1:IFX ANDI=38THENPRINT"WITH
WNDOW"
430 NEXTi:IFL<9THENM$=O$(50):GOSUB2:M$=O$(49):GOSUB2:M$=O$(48):GOSUB2:J=1
435 M=L:IFJ=0THENPRINT"NOTHING"
440 M$="OBVIOUS EXITS ARE-":IFL=11THENM$=M$+" UP! DOWN"
450 IF(L=13ANDD=0)ORL=12THENM$=M$+" DOWN"
455 IF(L=14)THENM$=M$+" OUT, UP, DOWN"
460 FORI=1TO4:IFP(L,I)>0THENM$=M$+" *"+O$(I)
465 NEXTi:GOSUB2:GOTO9
475 IFS=45ANDL=3THEN525
480 IFS=36ANDL=2THENO$(36)=D$(0):L(3)=2:L(8)=2:GOTO9
485 IFS=36ANDL=10THENO$(44)=D$(0):L(5)=L:L(6)=L:GOTO9
490 IFS=21ANDL=12THEN535
495 IFB$<>"DO"THEN690
500 GOSUB705:IFI=5THEN9
505 IFL=23ORL=10THEN695
510 IFL<>4ANDL<>5THENPRINT"IT'S JAMMED!":GOTO9
515 IFL(17)=L THENGOSUB715:GOTO9
520 GOTO790
525 IFL(17)=L THENO$(45)="OPEN ARMORY":L(1)=L:L(2)=L:GOTO9
530 GOTO520
535 PRINT"WITH WHAT":INPUTA$:IFLEN(A$)>1THENA$LEFT$(A$,2):IFA$="PH"THEN820
540 IFA$<>"SC"THENPRINT"WON'T WORK!":GOTO
545 IFL(15)=0ANDW=1THENO$(27)="OPEN HATCH:L(22)=L:GOTO9
550 IFL(15)=0THENPRINT"THEY'RE PHILLIPS SREWS!":GOTO9
555 GOTO575
560 IF(S=17)AND(L=12)AND(L(22)=L)AND(L(10)=0)THENL(22)=99:GOTO570
565 IFS=17AND(L(12)<>L)THENL(10)=50:L(22)=L:GOTO795
566 IFS=11ANDL(5)=0THENS=12
570 IFS>7THENIF(L(S-7)=0)THENL(S-7)=L:C=C1:GOTO9
575 PRINT"DON'T HAVE IT":GOTO9
585 IFL(1)<>0THENPRINT"WITH WHAT":GOTO9
590 IFS=21THEN820
595 IFB$<>"DO"THENPRINT"NO EFFECT!":GOTO9
600 GOSUB705:IFI=5THEN9
605 GOSUB715:N=L:L=P(L,I):GOSUB715:L=N
606 IFL=10ORL=23THENZ=1
610 IFL=4ORL=5THENL(22)=L(10):L(10)=50:GOTO795
611 GOTO9
620 IFS<>11ANDS<>13THEN780
622 FORI=1TO40:IFL(I)=0AND(I<4ORI>6)THEN785
625 NEXTi:IFF=8THEN655
630 IFS=13ANDL(6)=0THENL(6)=-1:GOTO9
640 IFL(4)=0ANDL(5)>0ANDNOTL(6)THENL(4)=-1:O=P:GOTO9
645 IFL(5)=0ANDL(4)>0ANDNOTL(6)THENL(5)=-1:GOTO9
650 GOTO780
655 IFS=13ANDL(6)=-1THENL(6)=0:GOTO9
665 IFL(4)=-1ANDNOTL(6)ANDL(5)>0THENL(4)=0:P=O:O=0:GOTO9
670 IFL(5)=-1ANDNOTL(6)ANDL(4)>0THENL(5)=0:GOTO9
675 GOTO780
680 M$="SCREEN SAYS- ORBITAL DECAY CONTINUING":GOSUB2
685 M$="CONTACT WITH ATMOSPHERE IN"+STR$(U)+":"+RIGHT$(STR$(T),2)+" HOURS":GOSUB
2:GOTO9
690 M$=Z$:GOSUB2:PRINT"DOES NOT COMPUTE":GOTO9
695 IFL(4)=-1ORL(5)=-1THEN605
700 PRINT"AREA DEPRESSURIZED":PRINT"SPACESUIT REQUIRED":GOTO9
705 FORI=1TO4:IFP(L,I)<0THENRETURN
710 NEXTi:PRINT"WHAT DOOR?":RETURN
711 IFNOTL(4)ANDNOTL(5)THENPRINT"RERUTNEVDA YDRAH A"
712 IFL(4)<1ORL(5)<1THENI=0:GOSUB717
713 FORI=8TO26:IFL(I-7)=1THENGOSUB717
714 NEXTi:FORI=50TO48STEP-1:GOSUB717:NEXTi:GOTO9
715 FORJ=1TO4:P(L,J)=ABS(P(L,J)):NEXTj:RETURN
717 M$="":FORJ=LEN(O$(I))TO1STEP-1:M$=M$+MID$(O$(I),J,1):NEXTJ:M$=M$+" ":GOSUB2
:RETURN
720 IFL(4)<1ORL(5)<1ORL(10)=0THENPRINT"CAN'T FIT NOW!":GOTO365
725 L=13:M=L:D=RND(5):E=RND(8):GOTO365
730 IFL(22)<99THEN820
735 M$="HORRAY!! YOU SAVED THE ENTERPRISE AT"+STR$(U)+":"+RIGHT$(STR$(T),2):GOSU
B2:END
740 M$="SHIP SEVERLY DAMAGED FROM FREAK ION STORM":GOSUB2
745 PRINT"ENGINES DAMAGED":PRINT"TRANSPORTER OUT"
750 PRINT"ABANDONING SHIP IN":PRINT"SHUTTLECRAFT":GOTO9
755 IFL(22)=99THENPRINT"ENGINES READY":GOTO9
760 PRINTTAB(7)"WARNING":PRINT"EXTREMELY FRAGILE":M$=O$(17):GOSUB2
765 M$=D$(12)+" IS CRACKED!":GOSUB2
770 M$="STARTING ENGINES WILL RESULT IN AN ANTI-MATTER IMPLOSION":GOSUB2:GOTO9
780 PRINT"CAN'T DO IT!":GOTO9
785 PRINT"HANDS ARE FULL!":GOTO9
790 M$="AUTHORIZED PERSONS ONLY - PRESENT ID":GOSUB2:GOTO9
795 PRINT"THE VALVE IS CRACKED!":GOTO9
800 M$="YOU ARE FLOATING AWAY IN SPACE":GOSUB2:RETURN
805 M$="YOU ARE IN THE VACUUM OF SPACE!":GOSUB2:RETURN
810 FORI=1TO40IFP(L,I)<0THENM=ABS(P(L,I))
815 RETURN
820 PRINT"THE ENGINES IMPLODED!":FORI=0TO2500:NEXTi:FORI=1TO8
825 PRINTTAB(RND(50))"BOOM":NEXTi:GOTO845
830 GOSUB800:IFL(6)=0THENM$="CARRYING "+O$(13):GOSUB2
835 GOTO845
840 GOSUB805:IFL(4)=0ORL(5)=0THENM$="HOLDING A "+O$(11):GOSUB2
845 PRINTTAB(10)"YOU'RE DEAD!":END
850 PRINT"THE SHIP JUST CRASHED!"
852 M$="YOU'D BE UP FOR COURT-MARTIAL - IF YOU WERE STILL ALIVE.":GOSUB2:GOTO845
860 IFL=23ORL=1THENP(23,3)=-10:P(10,4)=-23:Z=0:GOTO9
865 GOTO780
900 DIMO$(50),D$(14)
920 FORI=1TO50:READO$(I):NEXTi:FORI=1TO14:READD$(I):NEXTi:DIML(40)
930 FORI=1TO40:READL(I):NEXTi:DIMP(23,4):FORI=1TO23:FORJ=1TO4
940 READP(I,J):NEXTJ:NEXT I:L(0)=1
950 P=13:O$(0)="SPACESUIT WITH POCKETS":D$(0)="OPEN LOCKER":RETURN
1280 DATANORTH,SOUTH,EAST,WEST,UP,DOWN,OUT
1290 DATAPHASER,KLINGAT,UNIFORMS,SPACESUIT,SPACESUIT
1300 DATAMAGNETIC BOOTS,FLASHLIGHT,SHOES,FLUX SENSOR
1310 DATAMAGNATOMIC VALVE
1320 DATASAURIAN BRANDY,PILLOW
1330 DATATRICORDER,HAMMER,ORDINARY SCREWDIVER
1340 DATASPANNER WRENCH,ID BADGE,PENCIL,MESSAGE TAPE
1350 DATAHATCH,POCKETS,CRACKED VALVE
1360 DATAMIRROR,MAIN VIEWSCREEN,IMPULSE ENGINES
1370 DATAUHURA'S PANEL,SPOCK'S POSITION,GYM EQUIPMENT
1380 DATALOCKERS,DETENTION CELLS,ENGINE FIRING BUTTON,FLASHING READOUT
1390 DATACONTROL PANEL,STARS,DILITHIUM CRYSTALS
1400 DATAOPEN SHUTTLEBAY DOORS
1410 DATASPACESUIT LOCKER,ARMORY,CLOSED DOOR,TURBOLIFT
1420 DATACOMPUTER TERMINAL,VENILATOR,VIEWPORT
1430 DATAIN A CABIN,IN A GYM,IN SECURITY,IN ENGINEERING
1435 DATAIN PARTS STORAGE,IN A TRANSPORTE ROOM,IN A STORAGE LOCKER
1480 DATAIN AUXILIARY CONTROL,ON THE WRECKED BRIDGE OF THE STARSHIP ENTERPRISE
1485 DATAIN THE SHUTTLECRAFT BAY,ON THE STARBOARD ENGINE PYLON
1510 DATAON THE STARBOARD ENGINE,IN A VENTILATION DUCT,IN THE TURBOLIFT
1530 DATA50,50,50,7,50,50,7,50,5,5,1,1,4,4,4,4,50,50,50,12,50,50
1535 DATA1,9,4,9,9,2,2,3,8,8,6,10,4
1610 DATA10,10,3,50,50
1701 DATA0,0,21,0
1702 DATA-21,22,15,0
1703 DATA0,18,0,0
1704 DATA-5,0,0,19
1705 DATA0,-4,0,0
1706 DATA17,0,0,-7
1707 DATA0,0,-6,0
1708 DATA0,0,-22,0
1709 DATA0,0,0,0
1710 DATA0,0,0,-23
1711 DATA0,0,0,0
1712 DATA0,0,0,0
1713 DATA13,13,13,13
1714 DATA0,0,0,0
1715 DATA20,17,-16,2
1716 DATA18,19,0,-15
1717 DATA15,6,19,22
1718 DATA 3,16,0,20
1719 DATA16,0,4,17
1720 DATA0,15,18,21
1721 DATA0,-2,20,1
1722 DATA2,0,17,-8
1723 DATA0,0,-10,0
2000 REM 2010 REM CONVERTED BY COLIN APPLEBY FOR NEWBRAIN 11 NOVEMBER 2016
2020 REM DEBUGGED BY CHRIS DESPINIDIS

Colin Appleby
Posts: 93
Joined: Wed Mar 16, 2016 10:05 pm

Re: Source for "Trek adventure" Robert J. Retelle

#15 Post by Colin Appleby » Mon Nov 14, 2016 6:43 pm

Anyone got a Walkthrough for the "Trek Adventure".

Post Reply